home *** CD-ROM | disk | FTP | other *** search
/ Language/OS - Multiplatform Resource Library / LANGUAGE OS.iso / prolog / prlgbnch.lha / divide10.pl < prev    next >
Text File  |  1990-05-25  |  654b  |  36 lines
  1. % generated: 7 March 1990
  2. % option(s): 
  3. %
  4. %   (deriv) divide10
  5. %
  6. %   David H. D. Warren
  7. %
  8. %   symbolic derivative of ((((((((x/x)/x)/x)/x)/x)/x)/x)/x)/x
  9.  
  10. divide10 :- d(((((((((x/x)/x)/x)/x)/x)/x)/x)/x)/x,x,_).
  11.  
  12. d(U+V,X,DU+DV) :- !, 
  13.     d(U,X,DU),
  14.     d(V,X,DV).
  15. d(U-V,X,DU-DV) :- !,
  16.     d(U,X,DU),
  17.     d(V,X,DV).
  18. d(U*V,X,DU*V+U*DV) :- !,
  19.     d(U,X,DU),
  20.     d(V,X,DV).
  21. d(U/V,X,(DU*V-U*DV)/(^(V,2))) :- !,
  22.     d(U,X,DU),
  23.     d(V,X,DV).
  24. d(^(U,N),X,DU*N*(^(U,N1))) :- !, 
  25.     integer(N),
  26.     N1 is N-1,
  27.     d(U,X,DU).
  28. d(-U,X,-DU) :- !,
  29.     d(U,X,DU).
  30. d(exp(U),X,exp(U)*DU) :- !,
  31.     d(U,X,DU).
  32. d(log(U),X,DU/U) :- !,
  33.     d(U,X,DU).
  34. d(X,X,1) :- !.
  35. d(_,_,0).
  36.